1 GOSUB500
10 DIML$(5),E%(5):DV=4
15 PRINTTCHR$(9)CHR$(142)CHR$(8)"[147][144]ALIGN PRINT HEAD AS SHOWN"
20 PRINT"[144]  [223][157][157]  [146] [157][157][157]  [146][212][157][212][145][156][192][192] LABEL     [144]SIDE[157][157][157][157]VIEW"
25 PRINT"[156] [221][157][202][192] PRINT HEAD"
30 PRINT"[144]   [210][210][210][157][157][157][157][157][169][188][190][223][157][157][157]  "
35 PRINT"[156][145][145][145][201][157][202][192] LABEL"
37 PRINT"  [202][192] PRINT HEAD  [145][145][144]TOP [157][157][157][157]VIEW"
40 PRINT"     PUSH ANY KEY     ":GOSUB330
45 REM *** UPPER/LOWER CASE ***
50 PRINT"[147]UPPER & LOWER CASE?"
55 GOSUB330:IFA$="Y"THENC$=CHR$(17):PRINTCHR$(9)CHR$(14):GOTO65
60 C$=CHR$(15):PRINTCHR$(142)
65 FORI=1TO5:L$(I)="":E%(I)=0:NEXTI
70 REM *** INPUT LABEL ***
75 FORI=1TO5
80 PRINT"[147][144]YOU HAVE A MAXIMUM OF 5[146] ROWS WITH 33[146]"
82 PRINT"CHARACTORS PER ROW.":PRINT"IF THE 1ST CHARACTER";
85 PRINT" IS '^' THEN THE ROW   WILL BE DOUBLE WIDTH."
90 PRINT"LINE #"I
95 PRINT"  ";CHR$(34);CHR$(34);CHR$(20);:IFE%(I)THENPRINT"^";
100 PRINTL$(I):PRINT""
105 INPUTL$(I)
110 IFLEFT$(L$(I),1)="^"THENE%(I)=1:L$(I)=RIGHT$(L$(I),LEN(L$(I))-1):GOTO125
112 IFLEFT$(L$(I),1)="^"THENGOTO120
115 E%(I)=0
120 IFLEN(L$(I))>33-E%(I)*16THEN80
125 NEXTI
130 REM *** CENTER VERTICALLY ***
135 PRINT"CENTERED VERTICALLY?":GOSUB330:IFA$<>"Y"THEN185
140 K=0:FORI=1TO5:IFL$(I)<>""THENI=5:GOTO150
145 K=K+1
150 NEXTI
155 KK=0:FORI=1TO5:IFL$(6-I)<>""THENI=5:GOTO165
160 KK=KK+1
165 NEXTI
170 IFK+1<KKTHENFORI=1TOKK-K-2:FORJ=5TO2STEP-1
172 IFK+1<KKTHENL$(J)=L$(J-1):E%(J)=E%(J-1):NEXTJ:L$(1)="":NEXTI
175 IFK>KKTHENFORI=1TOK-KK-1:FORJ=1TO4:L$(J)=L$(J+1)
177 IFK>KKTHENE%(J)=E%(J+1):NEXTJ:L$(5)="":NEXTI
180 REM *** CHECK LABEL ***
185 PRINT"[147]LABEL CHECK"
190 PRINT"IF THE LINE IS REVERSED, THEN IT IS     DOUBLE  WIDTH LETTERS."
195 FORI=1TO5:IFE%(I)THENPRINT"[144]"I"[156]"L$(I):GOTO205
200 PRINT"[144]"I"[146][156]"L$(I)
205 NEXTI
210 PRINT"[144] IS THIS LABEL OK?"
215 GOSUB330:IFA$<>"Y"THEN75
220 PRINT"[147]HOW MANY WOULD YOU LIKE TO PRINT ":INPUTA$:N=VAL(A$):IFN<1THEN185
225 PRINT"C[146]ENTERED OR L[146]EFT JUSTIFIED?"
230 GOSUB330:IFA$="L"THENCH$="L":GOTO250
235 IFA$="C"THENCH$="C":GOTO265
240 GOTO230
245 REM *** LEFT JUSTIFY ***
250 K=1:FORI=2TO5:IFLEN(L$(I))>LEN(L$(K))THENK=I
255 NEXTI:A$="":FORI=1TOINT((33-E%(K)*16-LEN(L$(K)))/2):A$=A$+" ":NEXTI
260 REM *** SENT TO PRINTER ***
265 OPEN4,4:IF C$=CHR$(17)THEN CLOSE4:OPEN4,4,7
270 FORK=1TON:PRINT"LBL"K
275 GETZ$:IFZ$=""THEN295
280 IFZ$="Q"THENCLOSE4:GOTO180
285 PRINT"PUSH ANY KEY"
290 GETZ$:IFZ$=""THEN290
291 IFZ$="Q"THEN280
292 PRINT"            "
295 FORI=1TO5:PRINT#DV,C$;:X$="":IFE%(I)THENX$=CHR$(14)
300 IFCH$="L"THENPRINT#DV,C$+A$+X$+L$(I)+CHR$(15):GOTO310
305 A$="":FORJ=1TOINT((33-E%(I)*16-LEN(L$(I)))/2)
307 A$=A$+" ":NEXTJ:PRINT#DV,C$+X$+A$+L$(I)+CHR$(15)
310 NEXTI:PRINT#DV,CHR$(15)
315 NEXTK:CLOSE4
320 PRINT"DO YOU WANT TO DO SOME MORE LABELS?":GOSUB330:IFA$="Y"THEN185
325 GOTO63000
330 GETA$:IFA$=""THEN330
335 RETURN
500 PRINT"[147] DO YOU HAVE A PRINTER?"
502 POKE198,0:WAIT198,1:GETA$:IFA$<>"Y"ANDA$<>"N"THENPOKE53280,RND(1)*15:GOTO502
504 IFA$="Y"THENRETURN
506 :
510 PRINT"[147]SORRY...THIS PROGRAM REQUIRES A PRINTER."
520 FORDL=1TO2000:NEXT:GOTO63100
530 :
63000 REM  CONNECT BACK TO L.S.
63010 :
63100 PRINT"[147]LOAD"CHR$(34)"PAYLOAD"CHR$(34)",8":PRINT"RUN"
63102 POKE631,13:POKE632,13:POKE198,2:END